有时候会遇到上班地方的网络需要设置静态IP地址上网，家里的网络是自动获取IP地址上网的，而且两个网络是不一样的，比如家里的是10.0.0.1/24 上班地方的是 192.168.1.1/16 或者/24 每次都要手动设置会比较麻烦，也不容易记，为了方便，可以通过下面的bat脚本进行自动设置IP地址，下载后解压修改相应的地址双击即可使用

点此下载

修改 注意：NAME=以太网 要根据实际情况修改，有的是“以太网 1” 或“以太网 2”
代码： 
@echo off
rem 强制获取管理员权限
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
rem //设置变量
set NAME="以太网"
rem //以下属性值可以根据需要更改
set ADDR=192.168.3.6
set MASK=255.255.255.0
set GATEWAY=192.168.3.1
set DNS1=114.114.114.114
set DNS2=223.5.5.5
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS
echo 当前可用操作有：
echo 1 设置为静态IP
echo 2 设置为动态IP
echo 3 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3
:1
echo 正在设置静态IP，请稍等...
rem //可以根据你的需要更改
echo IP地址 = %ADDR%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY%
netsh interface ipv4 set address name=%NAME% static addr=%ADDR% mask=%MASK% gateway=%GATEWAY% >nul
echo 首选DNS = %DNS1%
netsh interface ip set dns name=%NAME% source=static addr=%DNS1% register=PRIMARY >nul
echo 备用DNS = %DNS2%
netsh interface ipv4 add dns name=%NAME% addr=%DNS2% >nul
echo **********已设置为静态IP：%ADDR%***********
timeout /t 5
exit
:2
echo 正在设置动态IP，请稍等...
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address %NAME% dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns %NAME% dhcp
echo **********已设置为动态IP地址***********
timeout /t 5
exit
:3
exit
使用： 保存的时候选择ANSI编码 ansi 编辑好后双击打开 1，设置静态IP，2，设置dhcp自动获取IP，3，退出
  1. 设置静态IP 设置静态IP
  2. dhcp设置动态获取IP DHCP获取IP